1:
2:
3:
4:
5:
6:
7:
8:
9:
10:
11:
12:
13:
14:
15:
16:
17:
18:
19:
20:
21:
22:
23:
24:
25:
26:
27:
28:
29:
30:
31:
32:
33:
34:
35:
36:
37:
38:
39:
40:
41:
42:
43:
44:
45:
46:
47:
48:
49:
50:
51:
52:
53:
54:
55:
56:
57:
58:
59:
60:
61:
62:
63:
64:
65:
66:
67:
68:
69:
70:
71:
72:
73:
74:
75:
76:
77:
78:
79:
80:
81:
82:
83:
84:
85:
86:
87:
88:
89:
90:
91:
92:
93:
94:
95:
96:
97:
98:
99:
100:
101:
102:
103:
104:
105:
106:
107:
108:
109:
110:
111:
112:
113:
114:
115:
116:
117:
118:
119:
120:
121:
122:
123:
124:
125:
126:

/*
	im radinat:

	trigger_use erstellen und ein targetname mit "door_1" geben
	dann soviele türen wie du willst erstellen (zB eine links, eine rechts)
	diese türen dann alle zu script_brushmodels oder zu script_models machen, je nachdem ob sie aus brushes oder aus xmodels bestehen
	dann deinen trigger anwählen, danach eine tür (reihenfolge beachten, und jede tür einzeln!) und W drücken, nun sollte eine 
	linie vom trigger zur tür zeigen
	das selbe mit den anderen türen machen
	auf diese weise wird dem trigger ein "target" von "auto01 irgendwas" zugeweisen, und die tür erhalten automatisch ein "targetname" mit
	"auto01 irgendwas", sodass wir später die türen dem trigger zuordnen können
	dann den trigger wieder anwählen und ein KVP (key-value-pair) mit "script_noteworthy" und "1.5;3.0" zuordnen
	die erste zahl 1.5 stellt hier dabei die zeit die die tür zum öffnen/schließen braucht dar, die zweite zahl, wie lange die tür offen bleiben soll
	dann setzt du beide türen so, wie sie in der map sein sollen wenn der trigger betätigt wird (zB geöffnet)
	dann wählst du jede tür einzeln an und gibts ihnen jeweils ein KVP von "script_target" und als value die aktuelle position der tür!
	auf diese position bewegt sich dann später die tür beim zB öffnen
	danach setzt du beide türen dahin wo sie sein sollen wenn der trigger nicht betätigt sein soll (zB geschlossen)

	das sollte es soweit gewesen sein, ich kommentier jz noch etwas mein script aus
*/
	
	
door_1_init() //das am start vom spiel aufrufen
{
	door_1_trigs = getEntArray( "door_1" , "targetname" );//alle trigger mit door_1 als targetname erfassen

	if( isDefined( door_1_trigs ) && door_1_trigs.size )
	{
		for( i = 0 ; i < door_1_trigs.size ; i++ )
		{
			door_1_trigs[i] thread door_1_think(); //durch jeden einzelnen trigger gehen und jeweils think()-funktion aufrufen lassen
		}
	}
}

door_1_think()
{
	//self ist hier der trigger!

	//falls keine türen mit W verbunden sind, ist hier schluss
	if( !isDefined( self.target ) )
		return iPrintLn( "door_1 at " + self.origin + " has no target defined!" );

	//self target wurde mit dem verbinden von tür und trigger automatisch erstellt und sollte "auto01 irgendwas" sein
	//muss aber nicht extra aufgerufen werden, einfach so wies hier unten steht =)
	self.doors = getEntArray( self.target , "targetname" ); //alle zum trigger gehörigen türen erfassen

	data = self.script_noteworthy; //falls du ein script_noteworthy mit den zeiten angegeben hast, werden diese hier erfasst

	moveTime = 1.5;
	openTime = 3.0;

	if( isDefined( data ) )//text bei jedem ';' splitten
		data = strTok( data , ";" );

	if( isDefined( data[0] ) ) //da es keine float() funktion gibt, hier ein kleiner workaround, sodass strings zu float konvertiert werden und weitergearbeitet werden kann
	{
		setCvar( "tmp" , data[0] );
		moveTime = getCvarFloat( "tmp" ) + 0.05;
	}

	if( isDefined( data[1] ) )
	{
		setCvar( "tmp" , data[1] );
		openTime = getCvarFloat( "tmp" ) + 0.05;
	}

	doors = [];

	//jetzt jede tür durchlaufen
	for( i = 0 ; i < self.doors.size ; i++ )
	{
		door = self.doors[i];

		//falls kein script_target (=zielposition) vorhanden ist, wird diese tür ignoriert!
		if( !isDefined( door.script_target ) )
		{
			iPrintLn( "door at " + door.origin + " has no script_target!" );

			continue;
		}

		//jetzt den einzelnen türen ihre start und zielposition merken lassen
		door.startPos = door.origin;
		door.goalPos = door.script_target;

		//tür scheint in ordnung zu sein, also merken
		doors[doors.size] = door;
	}

	//alle korrekten türen jetzt merken
	self.doors = doors;

	while( true )
	{
		self waittill( "trigger" , player ); //warten bis ein spieler den trigger aktiviert

		//jetzt jede tür ansprechen
		for( i = 0 ; i < self.doors.size ; i++ )
		{
			door = self.doors[i];

			//tür bewegt sich auf zielposition
			door moveTo( door.goalPos , moveTime , moveTime * 0.5 , moveTime * 0.5 );
		}

		//trigger wird hier deaktiviert, sodass anzeige kurz verschwindet, kannst du auch löschen wenn du magst
		self.origin -= ( 0 , 0 , 100000 );

		//warten, warten, warten.... jetzt gehts wieder zu ;-)
		wait( openTime );

		//jetzt wieder jede tür ansprechen
		for( i = 0 ; i < self.doors.size ; i++ )
		{
			door = self.doors[i];

			//tür wieder auf anfangsposition
			door moveTo( door.startPos , moveTime , moveTime * 0.5 , moveTime * 0.5 );
		}

		//trigger wieder aufg alte position
		self.origin += ( 0 , 0 , 100000 );
	}
}